***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jun 04, 2021                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt BZX584C12 A K 
.param
+vc0 = 1.046e-10	vc1 = 2.086e-11		vc2 = 1.000		vc3 = 3.703e-12		vc4 = 4.337e-1
+tc1 = 1.051e-2		tc2 = 1.021e-2		tc3 = 5.221e-3		tc4 = 1.801e-2
.func irexp(v) {(vc0+vc1*v^vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irexp(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1
***** dc model parameter *****
+ is = 4.595e-15	   n = 1.092		  rs = 4.313e-1
+ibv = 5.0e-3		 nbv = 1.0		  bv = 12
+ikf = 2.077e-2
***** capacitance parameter *****
+cjo = 3.564e-11	   m = 3.301e-1		  vj = 5.771e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.134		 xti = 3
+trs1 = -1.025e-4	trs2 = 1.385e-6		tikf = 1.0e-2
+tbv1 = 6.491e-4	tbv2 = 6.579e-8	
.ends BZX584C12
*$
